#globalfunctiondefinition
// SAP ITEM MASTER DATA
// 8.10.2020 Martin Heigl
// Note: Don't delete first line. This is for "speed loading"



// *********************************************************
// Right Click Menu 7.10.20 M.Heigl
// *********************************************************
global function form_rightclick
#jbs
if (ib_integration==false) {
	if (sbo_form.mode == 1 and license.get("BEAS_BASIC")==true){
		if (sbo_items.item("14").specific.checked == true) sbo_form.menus.AddRightClick("beas_invhistory","t:Teilekonto","1","s:inventoryhistory.bmp",false,true,2);
		sbo_form.menus.AddRightClick("beas_itemmaster","t:Artikelstamm erweitert","1","s:logo.bmp",false,true,3,
		"window.openwindow('artikel_Edit.psr',{s_parm1:is_itemcode});");
		sbo_form.menus.AddRightClick("beas_itemstructur","t:Strukturansicht","1","s:treeview.bmp",false,true,4);
		}
		return 0;
	}

// Duplicate / Add 
sbo_form.menus.AddRightClick("beas_addi","t:extendedCreation","0","s:add.bmp",false,true,1);

if (sbo_form.mode == 0) return 0;

// Reload ...
if (is_itemcode!=sbo_items.item("5").Specific.Value) form_load();

sbo_form.menus.AddRightClick("beas_copyi","t:extendedDuplicate","0","s:duplicate.bmp",false,true,2);

// Extended Production
let lm=sbo_form.menus.AddRightClick("beas_ext","t:Erweiterte Produktion","2","s:logo.bmp",false,true,3);
let lms=lm.SubMenus;

if (sbo_items.item("14").specific.checked == true)
	lms.AddRightClick("beas_invhistory","t:Teilekonto","1","s:inventoryhistory.bmp",false,true,4);


 // Bom and Routing?			
if (sbo_items.item("beas_brkdc").value != "V" and sbo_items.item("beas_brkdc") != "O" and 
	sbo_items.item("beas_admc").value < 1){
	if  (sbo_items.item("49").value=="M" or company.companyStorage.mget("assistkaufteil ","N")!="N")
		{
		if (il_bomaccess == 1 ) 
			lms.AddRightClick("beas_itembom","t:Stückliste","1","s:bom.bmp",false,true,5,
						"window.openwindow('artikel_stlpos_browse',{s_parm1:is_itemcode});");
		if ( il_routingaccess == 1 ) 
		lms.AddRightClick("beas_itemrouting","t:Arbeitsplan","1","s:operation.bmp",false,true,6,
					"window.openwindow('artikel_arbplanpos_browse',{s_parm1:is_itemcode});");
	
		if ( il_routingaccess == 1 and il_bomaccess == 1 ) {
	
			lms.AddRightClick("beas_itemstrreport","t:Strukturreport","1","s:treeviewreport.bmp",false,true,15,
				"window.openwindow('artikel_strukturexport',{s_parm1:is_itemcode,as_itemcode:is_itemcode,as_typ:'view'});");

			lms.AddRightClick("beas_itemstructur","t:Strukturansicht","1","s:treeview.bmp",false,true,14);
			}

		}

}


lms.AddRightClick("beas_itemqc","t:Qualitätssicherung","1","b:qc_header.bmp",false,true,10,
				"window.openwindow('qs_qsverweis',{s_parm1:is_itemcode});");

let result=sql.select count("ItemCode") from "BEAS_OITM_PRODUKTKONFIGURATOR" WHERE "ItemCode" = :is_itemcode;
if (result > 0)
	lms.AddRightClick("beas_itemconfig","t:Produktkonfigurator","1","s:configurator.bmp",false,true,11,
				"window.openwindow('artikel_produktkonfigurator',{s_parm1:is_itemcode});");

lms.AddRightClick("beas_itemremarks","t:Erweiterte Beschreibung","1","s:description.bmp",false,true,5,
	"window.openwindow('artikel_description',{s_parm1:is_itemcode,ab_fromParent:true});");

if (company.companyStorage.mget("itemparameter","N")=="J")
	lms.AddRightClick("beas_itemparameter","t:Parameter","1","s:parameter.bmp",false,true,7,
		"window.openwindow('artikel_edit_parameter',{s_parm1:is_itemcode});");

if (sbo_form.mode == 1) {
	if (company.companyStorage.mget("artikel_variante","J") != "N" and sbo_items.item("49").value=="M")
		lms.AddRightClick("beas_itemvariants","t:Varianten","1","s:variant.bmp",false,true,9,
				"window.openwindow('artikel_edit_shortvariant',{s_parm1:is_itemcode});");

}
if (company.companyStorage.mget("modul_caft","N")=="J" )
		lms.AddRightClick("beas_variantscript","t:Varianten Script","1","s:variant_script.bmp",false,true,10);
	

// Used in, 
lms.AddRightClick("beas_usedin","t:Verbaut in","1","s:usedin.bmp",false,true,1,
				"window.openwindow('artikel_revisionnumbercontrol',{s_parm1:is_itemcode,s_parm2:sbo_items.item('beas_vrsc').value})");
	


end global



// ************ Open Sub windows ************


global function form_beas_invhistory_click
object=ue_artikelstamm=teilekontostart=<is_itemcode>
end global
global function form_beas_itemstructur_click
object=ue_openwindow=beas_item_structur=<is_itemcode>
end global

// Item Version functions
global function item_beas_vrsb_click
openchild=artikel_version_browse.psr<tab>s_parm1=<is_itemcode>
end global
global function item_beas_vrsl_click
jbs.window.openwindow("artikel_version_edit",{s_parm1:is_itemcode,s_parm2:sbo_items.item("beas_vrsc").Specific.Value});
end global
global function item_beas_vrsc_click
#jbs
if (is_itemcode != "") {
  let r=sqlStatement.execute({select "Version","DESCRIPTION" from "BEAS_ITEM_VERSION" where "ItemCode"=:is_itemcode order by "Version"});
  sbo_Items.item("beas_vrsc").Specific.ValidValues.Add(r);
  }
return 0;  
end global
// Raw Material
global function item_beas_wstb_click
openchild=basis_wst_browse.psr
end global
global function item_beas_wstc_click
#jbs
if (sbo_Form.lastItemFocus != "beas_wstc"){
let r=sqlStatement.execute({select "WST_ID","BEZ" from "BEAS_WST" order by "WST_ID"});
sbo_Items.item("beas_wstc").Specific.ValidValues.Add(r,true);
}
end global
// MaterialGroup
global function item_beas_mgrpb_click
openchild=basis_materialgruppe_browse
end global
global function item_beas_mgrpl_click
jbs.window.openwindow("basis_materialgruppe_edit",{s_parm1:sbo_items.item("beas_mgrpc").Value});
end global
global function item_beas_mgrpc_click
#jbs
if (is_itemcode != "") { 
let r=sqlStatement.execute({select "GRUPPE","ZUSATZINFO" from "BEAS_MATGRP" order by "GRUPPE"});
sbo_Items.item("beas_mgrpc").Specific.ValidValues.Add(r,TRUE);
}
end global
// Cost Center
global function item_beas_prccc_click
#jbs
let r=sqlStatement.execute({select "PrcCode","PrcName" from "OPRC" where "Locked"='N' and "Active"='Y' order by "PrcCode"});
sbo_Items.item("beas_prccc").Specific.ValidValues.Add(r,TRUE);
end global
global function item_beas_prccb_click
jbs.sbo_application.ActivateMenuItem( "1793");
end global
// UoM
global function item_beas_puomc_click
#jbs
let r=bsl.get('ItemUoMList(:is_itemcode)?$mask=1&$orderby=UoMCode');
sbo_Items.item("beas_puomc").Specific.ValidValues.Add(r);
end global
global function item_beas_puomb_click
jbs.sbo_application.ActivateMenuItem( "1607");
end global
global function item_beas_puoml_click
jbs.window.openwindow("basis_me_edit",{s_parm1:sbo_items.item("beas_puomc").Value});
end global
// --------
global function item_beas_empc_click
#jbs
let r=sqlStatement.execute({select "USER_CODE","U_NAME" from "OUSR" where "Locked"='N' and "GROUPS"<>'99' order by "U_NAME"});
sbo_Items.item("beas_empc").Specific.ValidValues.Add(r,true);

end global
// scrap table
global function item_beas_scrtb_click
jbs.window.openwindow("stamm_verschnitt_browse");
end global
global function item_beas_scrtc_click
#jbs
let r=sqlStatement.execute({select "VERSCHN","BEZ" from "BEAS_VERSCHNITT" order by "VERSCHN"});
sbo_Items.item("beas_scrtc").Specific.ValidValues.Add(r,true);
end global
global function item_beas_scrtl_click
jbs.window.openwindow("stamm_verschnitt_werte_browse",{s_parm1:sbo_items.item("beas_scrtc").Value});
end global
// Calculation schema Dropdown
global function item_beas_schec_click
#jbs
let r=sqlStatement.execute({select "SCHEMA_ID","BEZ" from "BEAS_PK_SCHEMA" order by "SCHEMA_ID"});
sbo_Items.item("beas_schec").Specific.ValidValues.Add(r,true);
end global
// Open Calculation Window Calc Schema Browse
global function item_beas_scheb_click
jbs.window.openwindow("pk_schema_browse");
end global
// Open Calculation Window Calc Schema Edit 
global function item_beas_schel_click
jbs.window.openwindow("pk_schema_edit",{s_parm1:sbo_items.item("beas_schec").Value});
end global
// Warehouse Rule
global function item_beas_rulc_click
#jbs
let r=sqlStatement.execute({select "BinGroup","DESCRIPTION" from "BEAS_OWHS_BINDEF" WHERE "BinType"='G' order by "BinGroup"});
sbo_Items.item("beas_rulc").Specific.ValidValues.Add(r,true);
end global
global function item_beas_rulb_click
jbs.window.openwindow("bin_owhs_bindef_browse");
end global
global function item_beas_rull_click
jbs.window.openwindow("bin_owhs_bindef_edit",{s_parm1:sbo_items.item("beas_rulc").value,s_parm2:"G"});
end global


// *********************************************************
// Load Enrty 7.10.20 M.Heigl
// *********************************************************
global function form_load
#jbs
/*
sbo_form.freeze(true);
setvar is_itemcode=sbo_items.item("5").Specific.Value;
window.str_parm.s_parm1=sbo_items.item("5").Specific.Value;
let itemobject=ue_artikelstamm;
itemobject.bom_access(is_itemcode);
setvar il_bomaccess=return;
itemobject.routing_access(is_itemcode);
setvar il_routingaccess=return;
// Item Group locked, if Bom/Routing access not allowed
if (il_bomaccess != 1 or il_routingaccess != 1 )
	{
   sbo_items.item("39").enabled=false;
	}
 else
	{
   sbo_items.item("39").enabled=true;
	}

bs.destroy("itemobject");
// no intagration -> Exit
if (ib_integration==false) {
	sbo_form.freeze(false);
	return 0;
	}

// with integration - check fields
checkVisibleFields();

if (sbo_items.item("5").enabled == true) sbo_items.item("5").value=is_itemcode;

// ************ First load *************
// not all is possible in form load :-(
if (ib_firstload == true){
	ib_firstload=false;
	sbo_items.item("beas_brkdc").Specific.ExpandType=2;
	// Item Version Control Administartion
	let vadmin=sbo_items.item("beas_admc").Specific.ValidValues;
	vadmin.add("Standard=0,Erweiterte Ansicht=1,Separate Stückliste=2");
	vadmin=sbo_items.item("beas_admc").Specific.ExpandType=2;

	sbo_items.item("beas_clo2c").AffectsFormMode=false; // CalcUnit is temporarly field

	let acc=sbo_items.item("beas_accc").Specific;
	acc.ValidValues.Add("Detail= ,Tag=D,Woche=W,Monat=M,Summe=S");
	acc.ExpandType=2;

}

if (company.companyStorage.mget("artikel_spezgew","N") != "J") 	
		sbo_items.setUnVisible("beas_spgc","beas_spgt");
sbo_form.freeze(false);
*/
end global


// ********************* CHECK VISIBLE FIELDS ********************
// Related to current loaded item
global function checkVisibleFields
#jbs
if (ib_integration==false) return 0;

let lb_calcArea=true; // Display CalculationArea
sbo_form.freeze(true);
let breakdown=sbo_items.item("beas_brkdc").Specific.ValidValues;
sbo_items.item("beas_brkdc").Specific.ExpandType=2; // Breakdown
breakdown.Remove();
let bValue=sbo_items.item("beas_brkdc").Value;

// Search mode ...
if (sbo_form.mode == 0) {
		sbo_items.setUnVisible("beas_btcht","beas_btctc","beas_btctt","beas_slflc","beas_slflt","beas_vrsc","beas_vrst","beas_vrsb","beas_vrsct");
		sbo_items.setUnVisible("beas_ccct","beas_scheb","beas_schet","beas_schec","beas_schel","beas_clotc","beas_clott","beas_clo2c","beas_cprcc","beas_cprct");
		sbo_form.freeze(false);
		return 1;
}

// UoM Buttons related to UoMGroup
if (sbo_items.item("10002056").specific.Value == -1)
	   sbo_items.setVisible("beas_20b","beas_55b","beas_251b");
  else
	   sbo_items.setUnVisible("beas_20b","beas_55b","beas_251b");


// Manufacture
if(sbo_items.item("49").Value=="M") {
		
		// Production
		sbo_items.item("beas_scrnt").Specific.Caption="Ausschuss".utranslate()+" (%)";
		sbo_items.item("beas_scrtt").Specific.Caption="Ausschuss Tabelle".utranslate();
		
		// Breakdown
		breakdown.Add("Keine Auflösung=K,Auftragsbezogen=A,Lagerbezogen=B");
		
		if (sbo_items.item("14").specific.checked == false or bValue=="S") 
			breakdown.Add("S","Scheinbaugruppe".utranslate());
			
		if (bValue == "V") breakdown.Add("V","Setartikel".utranslate()); // for compatibility
		if (bValue == "O") breakdown.Add("O","Vorlage".utranslate());
		
		sbo_items.setVisible("beas_prelc","beas_prelt","beas_lotpc","beas_lotpt","beas_lotuo");
		if (company.companyStorage.mget("assistkaufteil","N")=="N") /* Calculation fields */
			sbo_items.setVisible("beas_ccct","beas_scheb","beas_schet","beas_schec","beas_schel","beas_clotc","beas_clott","beas_clo2c","beas_cprcc","beas_cprct");
		
		productionlotsizeuom();
	}
// Purchase Item	
else {
		sbo_items.item("beas_scrnt").Specific.Caption="Verschnitt".utranslate()+" (%)";
		sbo_items.item("beas_scrtt").Specific.Caption="Verschnitt Tabelle".utranslate();
		breakdown.Add("K","Keine Auflösung".utranslate());
		breakdown.Add("T","Beistellteile".utranslate());
		sbo_items.setUnVisible("beas_prelc","beas_prelt","beas_lotpc","beas_lotpt","beas_lotuo");
		if (company.companyStorage.mget("assistkaufteil","N")=="N")
		{   
			lb_calcArea=false;
			sbo_items.setUnVisible("beas_ccct","beas_scheb","beas_schet","beas_schec","beas_schel","beas_clotc","beas_clott","beas_clo2c","beas_cprcc","beas_cprct","beas_clotc","beas_calcb","beas_clpc");
		}
	}

// Calculation Lot Size
// Inser Production unit and BoM Unit in UoM Field
if (lb_calcArea==true) {
	let v=sbo_items.item("beas_clo2c");
	v.specific.ValidValues.remove();
	v.specific.ValidValues.add(sbo_items.item("beas_puomc").value,sbo_items.item("beas_puomc").value);
	if(sbo_items.item("beas_puomc").value!=sbo_items.item("251").value)
		v.specific.ValidValues.add(sbo_items.item("251").value,sbo_items.item("251").value);
	// Define, if Production Unit or WareHouse Unit for Lotsize is the standard
	let whsUnit=sbo_items.item("251").value;
	if (sbo_items.item("beas_puomc").value == "") sbo_items.item("beas_puomc").value =whsUnit;
	if (Number(sbo_DBDataSources.Item("OITM").GetValue("u_beas_calclotsizewounit",0)) > 0 and whsUnit != sbo_items.item("beas_puomc").value) 
		{
		sbo_items.setVisible("beas_clpc");
		sbo_items.setUnVisible("beas_clotc");
		sbo_items.item("beas_clo2c").Specific.Value = sbo_items.item("beas_puomc").value;
		}
	else {
		sbo_items.setUnVisible("beas_clpc");
		sbo_items.setVisible("beas_clotc");
		sbo_items.item("beas_clo2c").Specific.Value = sbo_items.item("251").value;
		}
}


// Batch / Serial number
if (sbo_items.item("162").value==2) 
	{
		sbo_items.item("beas_btcht").Specific.Caption="Batch".utranslate();
		let determination=sbo_items.item("beas_btctc");
		determination.Specific.ExpandType=2;
		let dv=determination.Specific.ValidValues;
		dv.Add("Automatische Chargenfindung=N,Charge laut Material=J,Manuelle Chargeneingabe=M");
		sbo_items.item("beas_btctt").Specific.Caption="Chargenfindung".utranslate();
		sbo_items.setVisible("beas_btcht","beas_btctc","beas_btctt","beas_slflc","beas_slflt");
	}

if (sbo_items.item("162").value==1)
	{
		sbo_items.item("beas_btcht").Specific.Caption="Serie".utranslate();
		sbo_items.item("beas_btctt").Specific.Caption="Serienummer".utranslate();
		let determination=sbo_items.item("beas_btctc");
		determination.Specific.ExpandType=2;
		let dv=determination.Specific.ValidValues;
		dv.Add("Automatische Serienummerfindung=N,Manuelle Serienummereingabe=M");
		sbo_items.setVisible("beas_btcht","beas_btctc","beas_btctt","beas_slflc","beas_slflt");
		
	}

if (sbo_items.item("162").value==0)
	sbo_items.setUnVisible("beas_btcht","beas_btctc","beas_btctt","beas_slflc","beas_slflt");

// Item Version Control. Admin only, if Versions existing and Version is defined
let vCount=sql.select count(*) from "BEAS_ITEM_VERSION" where "ItemCode"=:is_itemcode;
if (vCount > 0 and sbo_items.item("beas_vrsc").value != "")
	sbo_items.setVisible("beas_admc","beas_admt") ;
   else 
	sbo_items.setUnVisible("beas_admc","beas_admt") ;

// Version only, if Version is defined
if (sbo_items.item("beas_vrsc").value != "" or sbo_items.item("162").value != 0 or company.companyStorage.mget("allow_versions_normalitems","N") == "Y")
	sbo_items.setVisible("beas_vrsc","beas_vrst","beas_vrsb","beas_vrsct");
else	
	sbo_items.setUnVisible("beas_vrsc","beas_vrst","beas_vrsb","beas_vrsct");


sbo_form.freeze(false);
end global	


// *********************************************************
//  Delete Item only from BEAS - 2006/10/13 M.Heigl
// *********************************************************
global function form_1283_click
form=mode
setvar=e_mode=<value>
if <e_mode> n=  3 or <e_mode> n= 2  then
   meldung=fehler$please save the item first!
  return no_action
end if
object=ue_artikelstamm=artikel_del=<item 5>
if <return> = -1 then
  return failure
end if
return success
end global



// *********************************************************
// Update: Check if itemcode changed...
global function form_update
#jbs
/*
// Check uom - current disabled. We check nothing

if (sbo_items.item("14").specific.checked==True) {
	let r=sql.select (select count(*) from "OUOM" where "UomCode"=:sbo_items.item("55").specific.Value ) ,
		(select count(*) from "OUOM" where "UomCode"=:sbo_items.item("251").specific.Value ),
        (select count(*) from "OUOM" where "UomCode"=:sbo_items.item("20").specific.Value )  from "BEAS_DUMMY";
	if (r.value1 == 0 or r.value2 == 0 or r.value3 == 0)
		messagebox("NOTE: Wrong UoM Name in Purchase, Sales or Inventory area.".translate("wronguom"));
}
*/
// send to event system
setvar e_itemcode=sbo_items.item("5").specific.value;
beasScript{tools=createevent=itemchange==I=<itemcode>}
end global






global function item_beasfolder_click
#jbs
// beas folder became focus ...
sbo_form.PaneLevel=5020;
end global

global function form_open
#jbs
setvar il_bomaccess="-2"; // = not defined
setvar is_itemcode="";
var ib_integration=false;
var ib_firstload=true;

if (license.get("BEAS_BASIC")==false) return -1;
if (company.companyStorage.mget("item_window","1")=="0") return -1;

// Integration is activ!
ib_integration=true;

try {
	// Create Tab 
	let of=sbo_form.Items.Add("beasFolder",sbo_enum.it_FOLDER);
	of.left=sbo_form.Items.Item("11").left;
	//of.linkTo="27";
	of.specific.Caption="Advanced Production".translate();
	of.specific.Pane=5020;  
	of.AffectsFormMode=false;
	of.Specific.GroupWith("163"); 
	// Load all fields from PSR File
	sbo_form.LoadFromPsr();

	if (sbo_application.zoom != 100) {
		// Buttons for UOM -> Need exact place, if font size not 10.
		sbo_items.get("beas_20b").top = sbo_items.get("20").top;
		sbo_items.get("beas_20b").left= sbo_items.get("29").left;

		sbo_items.get("beas_55b").top = sbo_items.get("55").top;
		sbo_items.get("beas_55b").left = sbo_items.get("55").left + sbo_items.get("55").width + 2;

		sbo_items.get("beas_251b").top = sbo_items.get("251").top;
		sbo_items.get("beas_251b").left = sbo_items.get("251").left + sbo_items.get("251").width + 2;
		}
	}
catch (err) {
		messagebox("info","can't load advanced Beas Fields");
	};

end global;


// F1 Help
global function form_275_click
#jbs
if (ib_integration==false) return 0;
if (sbo_form.PaneLevel == 5020)  {
	jbs.application.help("Item_Master_Data");
	return -1;
	}
end global


// Changed Procurrement Method
global function item_49_itemchanged
#jbs
if (ib_integration==false) return 0;
checkVisibleFields();
end global

// Change item Version
global function item_beas_vrsc_itemchanged
checkVisibleFields()
end global

// Calc lot size UoM - change databound
global function item_beas_clo2c_itemchanged
#jbs
if(sbo_items.item("beas_clo2c").value == sbo_items.item("beas_puomc").value)
	{sbo_items.setVisible("beas_clpc");sbo_items.setUnVisible("beas_clotc");}
else
	{sbo_items.setUnVisible("beas_clpc");sbo_items.setVisible("beas_clotc");}
end global


// ********************** Change Calculation lot size by Stock unit
// Convert to other UoM
global function item_beas_clotc_itemchanged
#jbs
if (sbo_items.item("251").value == sbo_items.item("beas_puomc").Specific.Value) return 1;

// Get Spec.Weight
let specWeight=Number(sbo_items.item("beas_spgc").Specific.Value);
if (company.companyStorage.mget("artikel_spezgew","") != "J")
  let specWeight=Number(bsl.get('RawMaterial(:sbo_items.item("beas_wstc").Specific.Value)/Density/$value'));
  
// Convert to Production uom
  let r=bsl.UoMConversion.QtyConversion(
   sbo_items.item("beas_puomc").Specific.Value,
  sbo_items.item("251").Specific.Value,
  Number(sbo_DBDataSources.Item("OITM").GetValue("blength1",0)),
  Number(sbo_DBDataSources.Item("OITM").GetValue("bwidth1",0)),
  Number(sbo_DBDataSources.Item("OITM").GetValue("bweight1",0)),
  specWeight,
  Number(sbo_DBDataSources.Item("OITM").GetValue("ugpentry",0)),
  Number(sbo_items.item("beas_clotc").Specific.Value) 
  ).quantity;
  sbo_items.item("beas_clpc").Specific.Value=r;
  

end global


global function item_beas_calcb_click
#jbs
if (is_itemcode != "")
	if (sbo_form.mode==2) let lb_protect=true; else let lb_protect=false;
	window.openwindow("artikel_calculation",{s_parm1:is_itemcode,art_id:is_itemcode,ab_protect:lb_protect});
end global

// ********************** Change Calculation lot size by Production unit
// Convert to other UoM
global function item_beas_clpc_itemchanged
#jbs
// Get Spec.Weight
let specWeight=Number(sbo_items.item("beas_spgc").Specific.Value);
if (company.companyStorage.mget("artikel_spezgew","") != "J")
  let specWeight=Number(bsl.get('RawMaterial(:sbo_items.item("beas_wstc").Specific.Value)/Density/$value'));
  
// Convert to Production uom
  let r=bsl.UoMConversion.QtyConversion(
   sbo_items.item("251").Specific.Value,
   sbo_items.item("beas_puomc").Specific.Value,
  Number(sbo_DBDataSources.Item("OITM").GetValue("blength1",0)),
  Number(sbo_DBDataSources.Item("OITM").GetValue("bwidth1",0)),
  Number(sbo_DBDataSources.Item("OITM").GetValue("bweight1",0)),
  specWeight,
  Number(sbo_DBDataSources.Item("OITM").GetValue("ugpentry",0)),
  Number(sbo_items.item("beas_clpc").Specific.Value) 
  ).quantity;
  sbo_items.item("beas_clotc").Specific.Value=r;
  

end global


// ************************** Unit of MEasurement ***********************

// Changed Production unit
global function item_beas_puomc_itemchanged
#jbs
checkVisibleFields();
end global
// Purchase
global function item_beas_20b_click
#jbs
setvar is_changeObject="20";
let w=window.openwindow("uom_browse",{s_parm1:is_itemcode});
end global
// Sales
global function item_beas_55b_click
#jbs
setvar is_changeObject="55";
let w=window.openwindow("uom_browse",{s_parm1:is_itemcode});
end global
// Warehouse
global function item_beas_251b_click
#jbs
setvar is_changeObject="251";
let w=window.openwindow("uom_browse",{s_parm1:is_itemcode});
end global

// will be called from child window, example UoM window
// is_changeObject
// is_changeValue
global function itemchangeByChild
#jbs
sbo_items.item(is_changeObject).Specific.Value=is_changeValue
end global


global function item_20_itemchanged
#jbs
setvar is_changeValue=sbo_items.item("20").specific.Value;
uomchanged();
sbo_items.item("20").specific.Value=is_changeValue;
end global


global function item_55_itemchanged
#jbs
setvar is_changeValue=sbo_items.item("55").specific.Value;
uomchanged();
sbo_items.item("55").specific.Value=is_changeValue;
end global


global function item_251_itemchanged
#jbs
setvar is_changeValue=sbo_items.item("251").specific.Value;
uomchanged();
sbo_items.item("251").specific.Value=is_changeValue;
end global



global function uomchanged
#jbs
// in is_changeValue we need the curent
let ls_uom=sql.select "UomCode" from "OUOM" where lower("UomCode") =  lower(:is_changeValue);
if (sql.sqlcode == 100){
   let ls_search=is_changeValue+"%";
   let ls_uom=sql.select top 1 "UomCode" from "OUOM" where lower("UomCode") like lower(:ls_search) or lower("UomName") like  lower(:ls_search) ;
   }
if (sql.sqlcode == 0){
  setvar is_changeValue=ls_uom;
  }
else
  setvar is_changeValue=""; 
end global

// UoM Group
global function item_10002056_itemchanged
if (ib_integration==false) return 0;
checkVisibleFields()
end global

// *************** Variant Script **************
global function form_beas_variantscript_click
select "INHALT" into ls_script from "BEAS_OITM_PARAMETER" where "ItemCode"=<is_itemcode,dbstring> and "Parameter"='script-start'
programming=Script <is_itemcode>=variantscript1=this=var:ls_script==variantscript1
destroy=lpstore
declare=lpstore=ue_datastorevalues
lpstore=updatetable=beas_oitm_parameter
lpstore=select=* from "BEAS_OITM_PARAMETER" where "ItemCode"=<is_itemcode,dbstring> and "Parameter"='script-start'
if <lpstore.rowcount> n= 0 then
  lpstore.insertrow
  lpstore.itemcode=<itemcode>
  lpstore.parameter=script-start
  lpstore.inhalt=<ls_scripts>
  lpstore.erftstamp=<today,yyyy/mm/dd>
  lpstore.erfuser=<currentuser>
end if
lpstore.andtstamp=<today,yyyy/mm/dd>
lpstore.anduser=<currentuser>
lpstore.inhalt=<ls_script>
lpstore.update
destroy=lpstore
end global



// ********** Create New item **********
global function form_beas_addi_click
#jbs
setvar e_itemcode="";
sbo_form.mode=0;
if (sbo_form.mode !=0) return 1;
application.setPointer("Hourglass");
let result=window.openwindow("artikel_new",{s_parm1:"",modal:true});
if (e_itemcode=="") return 1;
sbo_items.item("5").specific.value=e_itemcode;
sbo_items.item("1").click()
end global

// ********** Duplicate Item **********
global function form_beas_copyi_click
#jbs
let ls_itemcode=is_itemcode;
sbo_form.mode=0;
if (sbo_form.mode !=0) return 1;
setvar e_itemcode="";
application.setPointer("Hourglass");
let result=window.openwindow("artikel_new",{s_parm1:"",art_id:ls_itemcode,modal:true});
if (e_itemcode=="") return 1;
sbo_items.item("5").specific.value=e_itemcode;
sbo_items.item("1").click()
end global


global function productionlotsizeuom
#jbs
let lotuo=sbo_Items.item("beas_lotuo").Specific;
lotuo.ValidValues.add(sbo_Items.item("beas_puomc").value+"=1,"+sbo_items.item("251").value+"=0");
lotuo.ExpandType=2;
end global